昨日のDIGのポッドキャストをDLするスクリプト
TBSラジオはポッドキャストを一週間で消すとかとんでもない事をぬかしております。そのため良い悪いにかかわらず全てDLしておかないといけません。
ニュース探求ラジオDIGは結構面白いのでとりあえず録っておきます。
http://www.tbsradio.jp/dig/index.html
ファイル名に法則性があるので以下の手順で自動DLしておけば慌てなくてすみます。特番等で変わった場合は対応できません。その時の事はまた考えますね。
んじゃ、具体的な方法です。
まず、システムにwgetあたりをインストールしておきます。
Wget for Windows
ここから
* Binaries
* Dependencies
の２つをダウンロードする。
両方解凍。
Dependenciesを解凍するとdllが何個か入っているのでこいつをwget.exeともどもc:\Windows\system32にコピーして終了。
と打ち込んでindex.htmlがダウンロードされればインストール完了
次に適当な場所にポッドキャストを保存するフォルダを作成します。OSのバージョンによっていろいろあるので省略。
私はWinXPで、データ用にD:ドライブが作ってあるので
D:\Users\takosan\PodCast なんてのを作りました。
そこにDIG用のフォルダを作成します。
D:\Users\Takosan\PodCast\TBSラジオ dig
こんな感じで作ると良いかと思います。
そこに以下のスクリプトをこんな名前Get_DIG.cmd で作成します。
中身はこうです。
- =-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
@echo off
echo WScript.echo(DateAdd("d",-1,date))>%tmp%\wday.vbs
for /f "tokens=*" %%i IN ('call cscript //nologo %tmp%\wday.vbs') DO @set dlDate=%%i
echo 昨日は%dlDate%
FOR /F "eol=;tokens=1 delims=/," %%i in ('echo %dlDate%') do set datey=%%i
FOR /F "eol=;tokens=2 delims=/," %%i in ('echo %dlDate%') do set datem=%%i
FOR /F "eol=;tokens=3 delims=/," %%i in ('echo %dlDate%') do set dated=%%i
set DT=%datey%%datem%%dated%
:/echo Rem wday.vbsの中身は1行で内容は"WScript.Quit(WeekDay(Date))"の１行
:Today
set logdir=%tmp%
if not exist dig%DT%. mkdir dig%DT%
pushd dig%DT%
if exist dig%DT%.cmd del dig%DT%.cmd
for %%a in (news dig)do echo wget -c http://podcast.tbsradio.jp/dig/files/%%a%DT%.mp3 >>dig%DT%.cmd
echo WScript.Quit(WeekDay("%datey%/%datem%/%dated%"))>%tmp%\wday.vbs
cscript /b %tmp%\wday.vbs
if errorlevel 7 echo 今日は土曜日 & goto END
if errorlevel 6 echo 今日は金曜日 & goto Fri
if errorlevel 5 echo 今日は木曜日 & goto Thr
if errorlevel 4 echo 今日は水曜日 & goto Wed
if errorlevel 3 echo 今日は火曜日 & goto Tue
if errorlevel 2 echo 今日は月曜日 & goto Mon
if errorlevel 1 echo 今日は日曜日 & goto END
if errorlevel 0 echo えっ？？
:Mon
for %%a in (takeyama nken)do echo wget -c http://podcast.tbsradio.jp/dig/files/%%a%DT%.mp3 >>dig%DT%.cmd
goto End
:Tue
for %%a in (jinbo) do echo wget -c http://podcast.tbsradio.jp/dig/files/%%a%DT%.mp3 >>dig%DT%.cmd
goto End
:Wed
for %%a in (fujiki) do echo wget -c http://podcast.tbsradio.jp/dig/files/%%a%DT%.mp3 >>dig%DT%.cmd
goto End
:Thr
for %%a in (ogiue) do echo wget -c http://podcast.tbsradio.jp/dig/files/%%a%DT%.mp3 >>dig%DT%.cmd
goto End
:Fri
for %%a in (ohne kubo) do echo wget -c http://podcast.tbsradio.jp/dig/files/%%a%DT%.mp3 >>dig%DT%.cmd
:End
call dig%DT%.cmd
popd
del %tmp%\wday.vbs
- =-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
実行すると、 dig20110114といったフォルダを作成し、中に dig20110114.cmd てなスクリプトを作り、これを呼び出してファイルをDLします。
これをタスクに登録して定期的に実行します。時刻は朝方が良いですかね。４時くらいには全て上がっていると思いますが、落ちてこないときは先ほどのdig20110114.cmdを再実行すれば良いです。
